Description

1.

${\displaystyle j={\frac {9\pi ^{2}v_{0}}{2\mathrm {T} ^{2}}}\cos \left({\frac {3\pi t}{\mathrm {T} }}\right)}$

${\displaystyle a={\frac {3\pi v_{0}}{2\mathrm {T} }}\sin \left({\frac {3\pi t}{\mathrm {T} }}\right)}$

${\displaystyle v={\frac {v_{0}}{2}}\left(1-\cos \left({\frac {3\pi t}{\mathrm {T} }}\right)\right)}$

${\displaystyle x={\frac {v_{0}}{2}}\left(t-{\frac {\mathrm {T} }{3\pi }}\sin \left({\frac {3\pi t}{\mathrm {T} }}\right)\right)}$

${\displaystyle a_{1}=0}$

${\displaystyle v_{1}=v_{0}}$

${\displaystyle x_{1}={\frac {v_{0}\mathrm {T} }{6}}}$

2.

${\displaystyle j=0}$

${\displaystyle a=0}$

${\displaystyle v=v_{0}}$

${\displaystyle x=v_{0}\left(t-{\frac {\mathrm {T} }{6}}\right)}$

${\displaystyle a_{2}=0}$

${\displaystyle v_{2}=v_{0}}$

${\displaystyle x_{2}={\frac {v_{0}\mathrm {T} }{2}}}$

3.

${\displaystyle j=-{\frac {9\pi ^{2}v_{0}}{2\mathrm {T} ^{2}}}\cos \left({\frac {3\pi t}{\mathrm {T} }}\right)}$

${\displaystyle a=-{\frac {3\pi v_{0}}{2\mathrm {T} }}\sin \left({\frac {3\pi t}{\mathrm {T} }}\right)}$

${\displaystyle v={\frac {v_{0}}{2}}\left(1+\cos \left({\frac {3\pi t}{\mathrm {T} }}\right)\right)}$

${\displaystyle x={\frac {v_{0}}{2}}\left(t+{\frac {\mathrm {T} }{3\pi }}\sin \left({\frac {3\pi t}{\mathrm {T} }}\right)+{\frac {\mathrm {T} }{3}}\right)}$

${\displaystyle a_{3}=0}$

${\displaystyle v_{1}=v_{0}}$

${\displaystyle x_{\mathrm {f} }={\frac {2v_{0}\mathrm {T} }{3}}}$

Max.

${\displaystyle v_{\max }=v_{0}={\frac {3x_{\mathrm {f} }}{2\mathrm {T} }}}$

${\displaystyle a_{\max }={\frac {3\pi v_{0}}{2\mathrm {T} }}={\frac {9\pi x_{\mathrm {f} }}{4\mathrm {T} ^{2}}}}$

${\displaystyle j_{\max }={\frac {9\pi ^{2}v_{0}}{2\mathrm {T} ^{2}}}={\frac {27\pi ^{2}x_{\mathrm {f} }}{4\mathrm {T} ^{3}}}}$

Scilab source

This media was created with Scilab, a free open-source software. Here is a listing of the Scilab source used to create this file.

function [t1, t2, t3] = indice(t)
    t1 = (t < 1/3);
    t2 = (t >= 1/3) & (t < 2/3);
    t3 = (t >= 2/3);
endfunction

function [j]=jerk(t)
    [t1, t2, t3] = indice(t);
    j = zeros(t);
    j(t1) = (9*%pi^2/2)*cos(3*%pi*t(t1));
    j(t2) = 0;
    j(t3) = -(9*%pi^2/2)*cos(3*%pi*t(t3));
endfunction

function [a]=acceleration(t)
    [t1, t2, t3] = indice(t);
    a = zeros(t);
    a(t1) = (3*%pi/2)*sin(3*%pi*t(t1));
    a(t2) = 0;
    a(t3) = -(3*%pi/2)*sin(3*%pi*t(t3));
    endfunction

function [v] = vitesse(t)
    [t1, t2, t3] = indice(t);
    v = zeros(t);
    v(t1) = (1/2)*(1 - cos(3*%pi*t(t1)));
    v(t2) = 1;
    v(t3) = (1/2)*(1 + cos(3*%pi*t(t3)));
endfunction

function [x] = position(t)
    [t1, t2, t3] = indice(t);
    x = zeros(t);
    x(t1) = (1/2)*(t(t1) - (1/3/%pi)*sin(3*%pi*t(t1)));
    x(t2) = t(t2) - 1/6;
    x(t3) = (1/2)*(t(t3) + (1/3/%pi)*sin(3*%pi*t(t3))) + 1/6;
endfunction

t = 0:0.005:1;

j = jerk(t);
a = acceleration(t);
v = vitesse(t);
x = position(t);

scf(0);
clf;

subplot(4, 1, 1)
plot(t, x)
xtitle("position", "t/T", "$x/(v_0 \mathrm{T})$")

subplot(4, 1, 2)
plot(t, v)
xtitle("vitesse", "t/T", "$v/(v_0)$")

subplot(4, 1, 3)
plot(t, a)
xtitle("accélération", "t/T", "$a\times \mathrm{T}/v_0$")

subplot(4, 1, 4)
xtitle("à-coup", "t/T", "$j \times \mathrm{T}^2/v_0$")
plot(t, j)

Conditions d’utilisation

Moi, en tant que détenteur des droits d’auteur sur cette œuvre, je la publie sous les licences suivantes :

Vous avez la permission de copier, distribuer et modifier ce document selon les termes de la GNU Free Documentation License version 1.2 ou toute version ultérieure publiée par la Free Software Foundation, sans sections inaltérables, sans texte de première page de couverture et sans texte de dernière page de couverture. Un exemplaire de la licence est inclus dans la section intitulée GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

Ce fichier est sous licence Creative Commons Attribution – Partage dans les Mêmes Conditions 3.0 (non transposée), 2.5 Générique, 2.0 Générique et 1.0 Générique.

Vous êtes libre :

• de partager – de copier, distribuer et transmettre cette œuvre
• d’adapter – de modifier cette œuvre

Sous les conditions suivantes :

• paternité – Vous devez donner les informations appropriées concernant l'auteur, fournir un lien vers la licence et indiquer si des modifications ont été faites. Vous pouvez faire cela par tout moyen raisonnable, mais en aucune façon suggérant que l’auteur vous soutient ou approuve l’utilisation que vous en faites.
• partage à l’identique – Si vous modifiez, transformez, ou vous basez sur cette œuvre, vous devez distribuer votre contribution sous la même licence ou une licence compatible avec celle de l’original.

https://creativecommons.org/licenses/by-sa/3.0CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue

Vous pouvez choisir l’une de ces licences.